@echo off

rem *** TorrenteLauncher v0.9 (by Gunner!!!)
@echo off
cls

rem *** Check previo!!!
	set input="%1"
	set input=%input:"=%
	if "%input%" == "" (
	  echo Error: Por favor suministre los parametros.
	  echo Uso: TorrenteLauncher "Nombre_de_Sala" Tipo_de_Sala Puerto Duracion
	  echo.  
	  exit /b 1
	)

echo.

rem *** Muestra parámetros introducidos - la validez de los parámetros está en manos del usuario!!!
		set "param=%~1"
		echo Nombre Servidor: %param:;=%
		echo Tipo Sala: %2
		rem *** Obtengo IP dinámica. En caso contrario sustituir la línea siguiente por "echo ###Mi_Dirección_IP###"
		curl ipinfo.io/ip
		rem *** Necesario para salto de línea
		echo.
		echo Puerto: %3 
		echo Duración: %4

echo.
echo.

rem *** Volcar datos a fichero de parámetros - (by ABC)!!!
rem ****************************************************
		rem *** Inicializa fichero con 1ª línea, parámetro "Nombre de sala"
		echo %param:;=%> Parametros.TOL
		
		rem *** Línea 2: "Tipo de sala"
		echo %2>> Parametros.TOL
		
		rem *** Línea 3: "Dirección IP"
		rem *** Para averiguar IP externa usa el comando "curl" (incluido en W10)
		rem *** Obtengo IP dinámica. En caso contrario sustituir las tres líneas siguientes por "echo ###Mi_Dirección_IP###>> Parametros.txt"
		curl ipinfo.io/ip>> Parametros.TOL
		rem ***El "Echo." es necesario para introducir un salto de línea
		echo.>> Parametros.TOL

		rem *** Línea 4: "Puerto de red"
		echo %3>> Parametros.TOL

		rem *** Línea 5 (y última): "Duración Partida"
		echo %4>> Parametros.TOL

rem *** Fin volcado parámetros (by ABC)!!!
rem **************************************

rem *** Registra en el FTP la definición de sala - (By ABC)!!!
rem *** El usuario del FTP es >> MatchMaker
rem *** La password del FTP es >> TorrenteOnline1.1d
rem ********************************************************

	setlocal
	@echo off > %0.ftp
	>> %0.ftp echo open gunner.es
	>> %0.ftp echo MatchMaker
	>> %0.ftp echo TorrenteOnline1.1d
	>> %0.ftp echo mkdir
	>> %0.ftp echo "%param:;=%"
	>> %0.ftp echo cd
	>> %0.ftp echo "%param:;=%"
	>> %0.ftp echo put Parametros.TOL
	>> %0.ftp echo quit

	ftp -s:%0.ftp

rem *** Fin volcado al FTP
rem **********************

rem **** Llama al ejecutable del aplicativo y espera que termine. Una vez cargado debeis configurarlo convenientemente en los menús de TOL!!!
rem ***************************************************************

echo.
echo.
echo Lanzando TorrenteOnline y esperando a que termine!!!
echo.
echo.

Rem Lanza el Tipo_de_Sala Solicitada!!!
%2.exe

Rem Espera a que TorrenteOnline se cierre!!!
:LOOP_TOL
tasklist /FI "IMAGENAME eq Torrente.exe" | find /I "Torrente.exe" >nul
if %errorlevel%==0 (
    echo Esperando fin de "Torrente.exe".
    timeout /t 5 >nul
    goto LOOP_TOL
) else (
    echo "Torrente.exe" ha finalizado o no en memoria.
)

rem *** Fin de ejecución del aplicativo
rem ***********************************

rem *** Tras terminar la partida, elimina del FTP la definición de sala - (By ABC)!!!
rem *******************************************************************************

	setlocal
	@echo off > %0.ftp
	>> %0.ftp echo open gunner.es
	>> %0.ftp echo MatchMaker
	>> %0.ftp echo TorrenteOnline1.1d
	>> %0.ftp echo cd
	>> %0.ftp echo "%param:;=%"
	>> %0.ftp echo delete Parametros.TOL
	>> %0.ftp echo quit

	ftp -s:%0.ftp

rem *** Fin de eliminación del FTP!!!
rem *********************************

rem exit