@echo off

Rem *** Lanzador TOL v0.9 (by Gunner!!!)
@echo off
cls
setlocal enabledelayedexpansion

Rem *** Lanzador TOL v0.9 (by Gunner)

Rem *** Parámetrización por defecto si quiere registrarse la sala en el MatchMaker
Rem *** Los valores entre almohadillas han de ser sustituidos por los correctos, sin almohadillas y con un literal válido (Ejemlo: ###Mi_Sala-24x7### => Mi_Sala-24x7).

Rem Nombre con que quieres que se muestre la sala en el MatchMaker (hasta 15 caracteres SIN ESPACIOS)
Set NombreSala="###Mi_Clan_24x7###"
Rem Puerto de conexión a la partida (debe estar abierto en el Router)
Set Puerto=###8888###
Rem Duracion de la partida (por defecto 30 minutos)
Set Duracion=###30###

REM Leer el archivo de escenarios y mostrarlo con números de línea
set "file=ListadoSalas.txt"
set /a lineNum=0

for /f "tokens=*" %%A in (%file%) do (
    set /a lineNum+=1
    echo !lineNum! %%A
    set "line[!lineNum!]=%%A"
)

REM Pedir al usuario que elija un número de línea
echo.
set /p "choice=Elige un numero de linea/sala: "

REM Validar si la elección es un número válido
if not defined line[%choice%] (
    echo Numero de linea no valido. Abortando la ejecucion.
    exit /b
)

REM Obtener el primer parámetro de la línea elegida
for /f "tokens=1" %%B in ("!line[%choice%]!") do set "firstParam=%%B"

set /p respuesta="Registrar/mostrar la partida en el "MatchMaker" (s/n): "

if /i "%respuesta%"=="S" (
	REM Lanzar TorrenteLauncher con los parámetros necesarios
    Echo Ejecutando: TorrenteLauncher.bat %NombreSala% %firstParam% %Puerto% %Duracion%
	TorrenteLauncher.bat %NombreSala% %firstParam% %Puerto% %Duracion%
) else if /i "%respuesta%"=="N" (
	REM Lanzar el .exe con el primer parámetro de la línea elegida
	echo Ejecutando: %firstParam%.exe
	start "" "%firstParam%.exe"
) else (
    echo Respuesta no valida. Abortando la ejecucion.
    exit /b 1
)


